Salutare

De cateva zile ma invart pe langa astea doua de mi s-a pus pata. Nu pricep si pace care-i diferenta. Poate cineva sa-mi explice si mie, in dulcele grai moldovenesc, prin ce se deosebesc astea doua? Ce se poate face cu una si nu se poate face cu cealalta? Un exemplu ar fi nemaipomenit.

In momentul asta eu vad lucrurile asa: Pot sa determin o metoda sa se execute cu ajutorul lui RaiseEvent(), cand vreau io. Da' si bindevent face acelasi lucru. Sa zicem ca vreau ca o metoda de-a mea sa se execute ori de cate ori fac click pe un buton. Pot sa introduc un RaiseEvent in codul din buton. Da' la fel de bine pot sa BindEvent() metoda mea de event-ul Click() al butonului.

Nu mai pricep nimica. Ma lasa nervii frate. Ajutati un suflet pierdut.

Salut, Dan, si multumesc pentru raspuns. M-am uitat in codul atasat, am inteles cum functioneaza (de fapt, stiam cum functioneaza) dar din pacate nu raspunde la intrebarea mea initiala.

Daca inlocuiesc in codul atasat RaiseEvent(This, "Changed") cu un simplu apel al procedurii - This.Changed(), fereastra va continua sa functioneze fara nici o diferenta. BindEvent() se va lega de metoda Changed si ori de cate ori aia va fi apelata de undeva, metoda bind-uita se va executa si ea.

Tocmai asta nu reuseam sa inteleg eu: de ce sa BindEvent() la o metoda, si apoi sa RaiseEvent() acea metoda, cand simpla apelare a ei este suficienta? Ce-are in plus RaiseEvent() fata de simplul apel?

Remarci, sper, faptul ca am folosit timpul trecut. Intre timp m-am lamurit. Diferenta consta, supriza, supriza, din modul in care faci BindEvent. Mai exact, din parametrii aia suplimentari, numiti in help "flags". Ei bine, daca flags lipseste (adica e 0, valoarea implicita) sau daca e 1, intre RaiseEvent si apelul metodei nu e nici o diferenta din punctul de vedere al lui BindEvent. Acesta va exacuta cu ravna si insufletire codul metodei specificate in RaiseEvent sau in apelul propriu-zis.

In schimb, daca flags este 2 sau 3 lucrurile se schimba. RaiseEvent va determina BindEvent sa percuteze, in timp ce apelul metodei nu.

Uite o secventa de cod care este semnificativa pentru scenariul de mai sus:

*------ Primul obiect listener
Define Class Obj1 As custom
Procedure Init
    BindEvent(MyCustomClass,"CustomEvent",This,"HandleEvent")
EndProc

Procedure HandleEvent
    Wait Window This.Name
EndProc
EndDefine

*------ Al doilea obiect listener
Define Class Obj2 As Custom
Procedure Init
    BindEvent(MyCustomClass,"CustomEvent",This,"HandleEvent")
EndProc

Procedure HandleEvent
    Wait Window This.Name
EndProc
EndDefine

*------ Obiectul global
Define Class MyCustomClass As Custom
Procedure CustomEvent
EndProc
EndDefine

Ok. Salvam asta ca prg si rulam urmatoarele chestii din fereastra de comenzi:

Set Procedure To numeprg.prg
MyCustomClass = CreateObject("MyCustomClass")
Obj1 = CreateObject("Obj1")
Obj2 = CreateObject("Obj2")
*-- In acest moment obiectele sunt create, si obiectele Obj il sunt legate de metoda CustomEvent a lui MyCustomClass.
MyCustomClass.CustomEvent()
*-- Apar doua ferestre wait window. Corect, ne asteptam la asta.
RaiseEvent(MyCustomClass,"CustomEvent")
*-- Apar doua ferestre wait window. Corect, si la asta ne asteptam.
Deschidem din nou prg-ul si adaugam un 2 la coada primului BindEvent. Definitia primului obiect arata asa:

Define Class Obj1 As custom
Procedure Init
   BindEvent(MyCustomClass,"CustomEvent",This,"HandleEvent",2)
EndProc

Procedure HandleEvent
    Wait Window This.Name
EndProc
EndDefine

Bun. Rulam urmatoarele in Command window:

Set Procedure To numeprg.prg
MyCustomClass = CreateObject("MyCustomClass")
Obj1 = CreateObject("Obj1")
Obj2 = CreateObject("Obj2")
*-- In acest moment obiectele sunt create, si obiectele Obj il sunt legate de metoda CustomEvent a lui MyCustomClass.
MyCustomClass.CustomEvent()
*-- Apare numai o fereastra wait window, generata de obiectul 2
RaiseEvent(MyCustomClass, "MyCustomEvent")
*-- Apar ambele ferestre wait window.

Mai exact, cand e Bind() cu 2 sau 3, numai RaiseEvent determina executia codului din eveniment. Apelul metodei nu. Adica 2 sau 3 il fac pe BindEvent() sa bind-uiasca la EVENIMENT. Nu la METODA. Diferenta dintre 2 si 3 e ordinea in care se executa (daca e delegatul se executa inaintea evenimenului sau dupa) si nu e relevanta pentru problema ridicata.

Asta-i toata diferenta. Practic, BindEvent face diferenta dintre ele, din modul in care este setat flags.

O clipa, IE crash la upload :)

Refac textul

Foarte corect, Dan. Inteleg unde bati. Obiectele alea nu stiu unul de existenta altuia. Doar BindEvent() stie, si le leaga fara ca ele sa stie ce si cum. Si din momentul ala ele, fara sa aiba cod specific (care sa apeleze din unul metodele celuilalt) se comporta unitar si fac impreuna o treaba, nu conteaza ce.

Off topic - initiativa de a-l invita pe Ken nu-mi apartie, ci este a lui Sergiu Cazan. Sa fiu sincer, eu n-am indraznit sa-l chem. Da' Sergiu a avut mai mult nerv. (Apropo, are cineva idee de ce Sergiu nu s-a inregistrat pe forum?)