Search  
Thursday, May 24, 2012 ..:: Forum ::.. Register  Login
 Forum Minimize
Pentru a putea posta mesaje trebuie să vă înregistraţi.
Notă: Mesajele cu conţinut jignitor sau ilegal (inclusiv cereri de soft piratat) nu sunt acceptate şi vor fi şterse imediat .

Pentru a primi raspunsuri rapide si corecte, scrieti in mesaj ce intentionati sa faceti, ce mesaj de eroare primiti, in ce context si in urma caror actiuni. De asemenea, mentionati versiunea de FoxPro in care lucrati!
Dacă nu specificați versiunea, se consideră VFP 9.0 SP2.
SearchForum Home
  Visual FoxPro  Office Automation  Functia AddPara...
 Functia AddParagraph
 
 10/28/2008 8:02:45 PM
User is offlinedalinx
124 posts
5th


Functia AddParagraph
 (N/A)
Va salut !

Doresc sa inserez un nou paragraf in word cu functia:  AddParagraph(oWord, '') dar primesc mesajul "function AddParagraph does not exist !"
Nu shtiu cum sa remediez problema !

Va multumesc mult pentru ajutor !
 10/28/2008 9:37:13 PM
User is offlineDaniel Buduru
2334 posts
1st




Re: Functia AddParagraph
 (N/A)
 dalinx wrote
Va salut !

Doresc sa inserez un nou paragraf in word cu functia:  AddParagraph(oWord, '') dar primesc mesajul "function AddParagraph does not exist !"
Nu shtiu cum sa remediez problema !

Va multumesc mult pentru ajutor !


AddParagraph() nu este o functie nativa VFP, ci o functie utilizator.
Cauta mai bine acolo unde ai gasit exemplul, ar trebui sa o gasesti acolo.
Daniel Buduru
 10/29/2008 10:27:31 AM
User is offlinedalinx
124 posts
5th


Re: Functia AddParagraph
 (N/A)
Intradevar nu este o functie nativa VFP, dar intr-un alt form culmea este ca o accepta !?
Nu shtiu cum ?!
Ceea ce doresc eu este sa construiesc un fisier word cu date dintr-o tabela VFP 9.0.
 10/29/2008 10:32:34 AM
User is offlinedalinx
124 posts
5th


Re: Functia AddParagraph
 (N/A)
Va trimit exemplul unde aceasta functie merge:

LPARAMETERS data_reg_caracter
STORE '' TO m.data_reg_caracter

#Define wdStory 6

lcNume = 'c:\temp\adeverinta_construita'
lcCale = 'c:\temp'
oWord = Createobject("word.application")
oWord.Visible = .T.
oWord.DisplayAlerts = .f.
Curdir=lcCale
oWord.ChangeFileOpenDirectory(Curdir)
oWord.Documents.Open(lcNume)

_temp1 = SUBSTR(ALLTRIM(m.cnp), 1, 1)
DO CASE
    CASE _temp1 = '1' OR _temp1 = '5'
        m.domnul_doamna = 'Domnul'
        m.domiciliat_domiciliata = 'domiciliat'
    CASE _temp1 = '2' OR _temp1 = '6'
        m.domnul_doamna = 'Doamna'
        m.domiciliat_domiciliata = 'domiciliata'
ENDCASE

IF EMPTY(ALLTRIM(m.cnp))
    m.cnp = m.cnp_strain
ENDIF

IF m.sector > 0
    m.sector_caracter = 'sector ' + ALLTRIM(STR(m.sector,1)) + ','
ELSE
    m.sector_caracter = ''
ENDIF

m.domnul_doamna = ALLTRIM(m.domnul_doamna)
m.domiciliat_domiciliata = ALLTRIM(m.domiciliat_domiciliata)
m.sector_caracter = ALLTRIM(m.sector_caracter)

WITH oWord
    .Selection.EndKey(6)
    .Selection.Font.Bold = .f.
    m.data_reg_caracter = ALLTRIM(DTOC(m.data_reg))
    .Selection.ParagraphFormat.Alignment = 1
    AddParagraph(oWord, 'Nr. reg.' + m.nr_reg + ' la ' + m.data_reg_caracter)
    .Selection.ParagraphFormat.Alignment = 3
    AddParagraph(oWord, '')
    .Selection.TypeText('       Adeverim prin prezenta ca ' + m.domnul_doamna + ' ')
    .Selection.Font.Bold = .t.
    .Selection.TypeText(m._gnume + '  ' + m._gprenume)
    .Selection.Font.Bold = .f.
    .Selection.TypeText(' ' + m.domiciliat_domiciliata + ' in ')
    .Selection.TypeText(m._glocalitate + ', ')
    .Selection.TypeText(m._gadresa + ', ')
    IF !EMPTY(ALLTRIM(m.sector_caracter))
        .Selection.TypeText(m.sector_caracter + ', ')
    ENDIF
    .Selection.TypeText('actul de identitate ' + m._gserie_act + ' ' + m._gnumar_act + ', ')
    .Selection.TypeText('CNP ' + m._gcnp + ', ')
    .Selection.TypeText('eliberat la data de ' + m._gla_data_de + ', ' + m._gspclep + ' ' + m._geliberat_de + ', ')
    .Selection.TypeText('are calitatea de membru .')
    .Selection.EndKey(6)
    AddParagraph(oWord, '')
    AddParagraph(oWord, '        Uniunea a dobandit calitatea de persoana juridica de utilitate publica .')
    AddParagraph(oWord, '        Certificam corectitudinea si legalitatea datelor inscrise in prezenta adeverinta.')
    AddParagraph(oWord, '', 2)
    .Selection.Font.Bold = .f.
    .Selection.ParagraphFormat.Alignment = 2
ENDWITH
 10/29/2008 10:49:47 AM
User is offlineDaniel Buduru
2334 posts
1st




Re: Functia AddParagraph
 (N/A)
 dalinx wrote
Intradevar nu este o functie nativa VFP, dar intr-un alt form culmea este ca o accepta !?
Nu shtiu cum ?!

Daca este acceptata in from, exista intr-o procedura sau in calea de acces vizibile din form.
Cauta comenzile SET PROCEDURE din accel form (inclusiv programul care il lanseaza), apoi cauta in programele listate in comanda aceasta functie. Cauta si AddParagraph.prg pe disc, desi sunt mari sanse sa fie intr-o procedura si nu in prg de sine statator.

Pune la inceputul procedurii in care merge liniile astea:

WAIT WINDOW (SET("Procedure"))
_cliptext=SET("Procedure")

Vei vedea ce proceduri sunt deschise. Le vei avea si in clipboard, poti face paste intr-un prg nou  ca sa le examinezi pe indelete.

Oricum, daca nu o gaseti, functia este asta:

PROCEDURE AddParagraph(toWord, tcText, tnParagraphs)
LOCAL lnCounter
WITH toWord.Selection
    IF PCOUNT() >= 2
        .TypeText(tcText)
    ENDIF
    IF PCOUNT() < 3 OR TYPE("tnParagraphs") # "N"
        tnParagraphs = 1
    ENDIF
    FOR lnCounter = 1 TO tnParagraphs
        .TypeParagraph
    ENDFOR
ENDWITH
RETURN
ENDPROC &&* AddParagraph


Daniel Buduru
 10/29/2008 11:02:59 AM
User is offlinedalinx
124 posts
5th


Re: Functia AddParagraph
 (N/A)
Asha este !
Am functia asta intr-o biblioteca !
Probabil ca am obosit !
Multumesc foarte mult pentru ca mi-atzi deschis ochii !
 Page 1 of 1
NextPreviousNo Rating
  Visual FoxPro  Office Automation  Functia AddPara...
Search  Forum Home         

 Google Ads Minimize
    

Copyright 2002-2010 Profox   Terms Of Use  Privacy Statement