Bun. Imi place atitudinea. Da-i bataie cu planul ala si cand esti gata vino cu el incoa'. (Apropo, planul ala se numeste analiza de sistem.) Cel mai probabil o sa suporte niste modificari cand il vom citi, si inca niste modificari cand te vei apuca efectiv de lucru. Dar inceputul e bun.

Astept ;)

Salut!

Pe de alta parte ma trebuie ţinut cont că: omul pleaca de la zero şi mai are maxim trei luni la dispoziţie, proiectul este pur didactic, adică nu va fi folosit niciodată pe bune într-o bibliotecă şi, după câte îmi dau seama, acolo la şcoala nu are de la cine învăţa .... Dacă scopul final este trecerea atestatului, proiectul trebuie privit mai simplist (se poate lua 10 şi cu rezolvarea ecuaţiei de gradul II). În acest caz, propun următorul set minimal de cerinţe:

- să se poată înregistra intrarea unei cărţi noi în bibliotecă: data, cartea, număr de exemplare achiziţionat

- să se poată înregistra împrumutul unei cărţi la un elev: data, cartea, elevul

- să se poată înregistra restituirea unei cărţi: data, elevul, cartea

Să vedem dacă absolventul ne spune de ce tabele are nevoie ca să memoreze informaţiile asta şi ce liste, statistici, etc îşi imaginează plecând de la aceste date.

User interface design is more an art than a science.  There are guidelines that can be used but the final resulting interface design depends on many unrelated issues. Issues like system requirements, user preferences, speed of data entry, existing interfaces, intuitiveness, aesthetics, system performance requirements, and others.
In this session we divided user interface designs into three categories, Process Centric, Data Centric, and Goal Centric. Applications were divided into two categories, Sovereign and Transient. To design an effective user interface the application must be classified into the appropriate category and then the interface style should be identified.  Only after you know these requirements can you begin to design an effective user interface.

 FUNCTION NewID(tcAlias) && se primeste un alias (deci o apelezi cu x = NewId("nume_tabela")
     LOCAL lcAlias, ; && astea-s declaratii de variabile. Pot sa lipseasca, da' nu-i frumos.
           lcID, ;
           lcOldReprocess, ;
           lnOldArea

     lnOldArea = SELECT() && lnOldArea va memora zona de lucru curenta, pentru ca ulterior
                          && programul va selecta alta tabela si trebuie sa se mute inapoi
                          && pe zona initiala inainte de a se inchide. Tot din categoria
                          && "nu-i frumos sa schimbi zona de lucru necontrolat."

     IF PARAMETERS() < 1 && PARAMETERS() intoarce numarul de parametri primiti in functie.
       lcAlias = UPPER(ALIAS()) && daca nu s-a primit nici unul, programul va considera
                                && ca se cere un id nou pentru tabela selectata in prealabil.
     ELSE
       lcAlias = UPPER(tcAlias) && in caz contrar se va folosi tabela specificata ca parametru.
     ENDIF
            && oricum ar fi, numele tabelei e stocat in variabila lcAlias, fiindca ne trebuie mai jos.

     lcID = ""
     lcOldReprocess = SET('REPROCESS') && programul va modifica valoarea lui Set Reprocess.
                                       && ca sa-l poata reconsitui la terminare trebuie sa memoreze cat era.

     *-- Lock until user presses Esc
     SET REPROCESS TO AUTOMATIC  && chestia asta determina foxul sa incerce la nesfarsit blocarea
                                 && unei inregistrari atunci cand se incearca blocarea. Alternativele
                                 && sunt "incearca un numar prestabilit de secunde" sau "incearca de un
                                 && numar prestabilit de ori". Nu se pot folosi aici - rutina asta trebuie
                                 && ori sa blocheze si sa-si faca treaba, ori sa nu blocheze si sa iasa.

     IF !USED("SETUP")
       USE tastrade!setup IN 0   && daca tabela "setup" nu e deschisa, o deschide intr-o zona de lucru noua ...
     ENDIF
     SELECT setup && ... si o selecteaza.

     IF SEEK(lcAlias, "setup", "key_name") && cauta numele tabelei (din variabila lcAlias). Functia SEEK()
                                           && cauta numele tabelei in campul key_name si, daca gaseste, se duce
                                           && pe inregistrarea aia. Daca nu, ajunge pe EOF() si returneaza .F.,
                                           && deci tot ce e in IF nu se executa deloc. ALtfel spus, daca trimiti
                                           && balarii ca parametru, nu se executa nimic.
       IF RLOCK()  && Incearca blocarea inregistrarii gasite. Din cauza lui SET REPROCESS AUTOMATIC de mai sus,
                   && programul va intepeni aici pana cand a) blocheaza inregistrarea sau b) userul apasa Esc.
                   && Dat fiind ca programul asta dureaza extrem de putin, sansele sa ajungi sa dai Esc sunt infime.
         lcID = setup.value && se ia valoarea urmatoare a id-ului tabelei specificate ca parametru intr-o variabila.
         REPLACE setup.value WITH ;
                 STR(VAL(ALLT(lcID)) + 1, LEN(setup.value)) && apoi se incrementeaza valoarea aia, ca sa fie disponibila la urmatorul apel al functiei.
         UNLOCK && deblocheaza tabela
       ENDIF
     ENDIF

    SELECT (lnOldArea) && selecteaza zona de lucru selectata initial
     SET REPROCESS TO lcOldReprocess && reconstituie SET REPROCESS

     RETURN lcID && returneaza id-ul.