:)

Release MyLog
sau
MyLog = .NULL.

Eu ti-as recomanda un VerboseLevel, ca sa poti filtra din clasa cantitatea de mesaje logate. mylog.verboselevel = 0 - se scriu numai mesajele critice, de genul MyLog.Msg = "0,Mesaj critic". MyLog.Msg = "2,Mesaj non-critic" nu ajunge in log decat daca MyLog.VerboseLevel >=2.

O sa fac un pustiu de bine si o sa postez codul clasei mele de auditare (din framework-ul pe care l-ai vazut la Oradea). Citeste cine vrea, intelege cine poate. Un singur comentariu am de adaugat: pentru fiecare linie de cod de mai jos am o explicatie foarte bine argumentata, chiar daca pare ca m-am complicat.

**************************************************
*-- Class: b_auditmgr (c:\dev\vfp\framework\common\libs\b_auditmgr.vcx)
*-- ParentClass: b_cus (c:\dev\vfp\framework\common\libs\b_controls.vcx)
*-- BaseClass: custom
*-- Time Stamp: 02/24/06 11:03:06 AM
*-- B-Layer Audit Manager class.
*

#INCLUDE "c:\dev\vfp\framework\common\include\main.h"
*

DEFINE CLASS b_auditmgr AS b_cus

*-- Full path of the audit file.
auditfilename = ""
*-- If .T., the audit file will be created automatically.
autocreateauditfile = .T.
*-- A string that will be used as separator.
logseparator = --------------------------------------------------------------------------------
*-- If .T., the content of the audit file won't be overwritten, even parameters specify so. Useful in debugging.
prohibitoverwritingauditfile = .F.
*-- Level of verbosity. 0 is minimum, 3 is maximum. Only the entries which have VerboseLevel parameter greater than this value will be logged.
verboselevel = 0

_memberdata = [<VFPData><memberdata name="auditfilename" type="property" display="AuditFileName"/><memberdata name="log" type="method" display="Log"/><memberdata name="checkauditfile" type="method" display="CheckAuditFile"/><memberdata name="writetoauditfile" type="method" display="WriteToAuditFile"/><memberdata name="autocreateauditfile" type="property" display="AutoCreateAuditFile"/><memberdata name="createauditfile" type="method" display="CreateAuditFile"/><memberdata name="logseparator" type="property" display="LogSeparator"/><memberdata name="prohibitoverwritingauditfile" type="property" display="ProhibitOverwritingAuditFile"/><memberdata name="verboselevel" type="property" display="VerboseLevel"/></VFPData>

Name = "b_auditmgr"

*-- Writes information in .AuditFileName file.
PROCEDURE log
**********************************************************************
* Program....: B-AuditMgr.Log()
* Version....:
* Author.....: Grigore Dolghin :: mailto:gdolghin@yahoo.com
* Date.......: 04 November 2005, 11:54:47
* Notice.....: Copyright © 2005, Class Software.
* Compiler...: Visual FoxPro 09.00.0000.3307 for Windows
* Abstract...:
* Changes....: Administrator, Created 04 November 2005 / 11:54:47
* Parameters.: tnVerboseLevel, integer. Level of verbosity - 0 to 3.
* ...........: tcLogEntry, character. Text to be logged.
* ...........: tlIncludeSeparator, boolean. If .T., a line will be
* ...........: drawn, to separate sessions.
* ...........: tlNewLoggingSession, boolean. If .T., a separator is
* ...........: drawn.
* Called by..:
* Purpose....: Writes the information in file specified in
* ...........: .AuditFileName property.
**********************************************************************
Lparameters tnVerboseLevel, tcLogEntry, tlIncludeSeparator, tlNewLoggingSession
Local ;
   llSuccess As Boolean, ;
   lcOldSetSafety As String

*** Parameters checking:
If Vartype(tnVerboseLevel) <> TypeNumeric Or ;
      Not Between(tnVerboseLevel,0,3)
   tnVerboseLevel = 3
EndIf

If Vartype(tcLogEntry) <> TypeCharacter Or ;
      Empty(tcLogEntry)
   Return llSuccess
EndIf

If Vartype(tlIncludeSeparator) <> TypeLogical
   tlIncludeSeparator = False
EndIf

If Vartype(tlNewLoggingSession) <> TypeLogical
   tlNewLoggingSession = False
EndIf

*** This method is called first time at very beginning, before
*** EnvironmentMgr to have any chance to set the environment.
*** For this reason I need to Set Safety Off by myself, because
*** it comes set to ON by default:
lcOldSafety = Set("Safety")
Set Safety Off

With This
   Do Case
      Case ! .CheckAuditFile(tlNewLoggingSession)
      Case ! .WriteToAuditFile(tnVerboseLevel, tcLogEntry, tlIncludeSeparator)
      Otherwise
         llSuccess = True
   EndCase
EndWith

Set Safety &lcOldSafety
Return llSuccess
ENDPROC

*-- Checks if audit file does exists and it is ready to be used.
PROCEDURE checkauditfile
**********************************************************************
* Program....: B-AuditMgr.CheckAuditFile
* Version....:
* Author.....: Grigore Dolghin :: mailto:gdolghin@yahoo.com
* Date.......: 04 November 2005, 12:01:34
* Notice.....: Copyright © 2005, Class Software.
* Compiler...: Visual FoxPro 09.00.0000.3307 for Windows
* Abstract...:
* Changes....: Administrator, Created 04 November 2005 / 12:01:34
* Parameters.: tlNewLoggingSession, boolean. If .T., the audit file
* ...........: content is erased.
* Called by..:
* Purpose....: Checks if audit file does exists and it is ready to be
* ...........: used.
**********************************************************************
Lparameters tlNewLoggingSession
Local llSuccess As Boolean

With This
   If Not Empty(.AuditFileName)
   *** We have an audit file defined.
      If File(FullPath(.AuditFileName))
      *** It does exists...
         llSuccess = True
         If tlNewLoggingSession And Not .ProhibitOverwritingAuditFile
         *** however, user said it should be overwritten
            llSuccess = .CreateAuditFile()
         EndIf
      Else
      *** The audit file doesn't exist on disk. Let's see if we
      *** can create it:
         If .AutoCreateAuditFile
         *** Yes, we can.
            llSuccess = .CreateAuditFile()
         EndIf
      EndIf
   EndIf
EndWith
Return llSuccess
ENDPROC

*-- Records the operation to audit file.
PROCEDURE writetoauditfile
**********************************************************************
* Program....: B-AuditMgr.WriteToAuditFile()
* Version....:
* Author.....: Grigore Dolghin :: mailto:gdolghin@yahoo.com
* Date.......: 04 November 2005, 12:12:19
* Notice.....: Copyright © 2005, Class Software.
* Compiler...: Visual FoxPro 09.00.0000.3307 for Windows
* Abstract...:
* Changes....: Administrator, Created 04 November 2005 / 12:12:19
* Parameters.: tnVerboseLevel, numeric. Level of verbosity.
* ...........: tcLogEntry, character. Text to be logged.
* ...........: tlIncludeSeparator, boolean. If .T., a line is drawn.
* Called by..:
* Purpose....: Records the operation to audit file. The operation will
* ...........: be logged only if the tnVerboseLevel parameter is
* ...........: equal or greater than .VerboseLevel property.
**********************************************************************
Lparameters tnVerboseLevel, tcLogEntry, tlIncludeSeparator
Local ;
      llSuccess As Boolean, ;
      lcDateTime As String, ;
      lnResult As String

lcDateTime = Padr(Ttoc(Datetime()), 23, " ") + ": "
tcLogEntry = tcLogEntry + CRLF

With This
   If .VerboseLevel >= tnVerboseLevel
      If tlIncludeSeparator
         lnResult = StrToFile(CRLF + .LogSeparator + CRLF, .AuditFileName, 1)
      EndIf
      lnResult = StrToFile(lcDateTime + tcLogEntry, .AuditFileName, 1)
      llSuccess = (lnResult <> 0)
   Else
      *** The operation has verbosity level lower than acceptable. However,
      *** I'll return True, because there is no error.
      llSuccess = True
   EndIf
EndWith
Return llSuccess
ENDPROC

*-- Creates the audit file.
PROCEDURE createauditfile
**********************************************************************
* Program....: B-AuditMgr.CreateAuditFile
* Version....:
* Author.....: Grigore Dolghin :: mailto:gdolghin@yahoo.com
* Date.......: 04 November 2005, 12:55:05
* Notice.....: Copyright © 2005, Class Software.
* Compiler...: Visual FoxPro 09.00.0000.3307 for Windows
* Abstract...:
* Changes....: Administrator, Created 04 November 2005 / 12:55:05
* Parameters.:
* Called by..:
* Purpose....: Creates the audit file, if .AutoCreateAudit file is
* ...........: .T. and the file is missing from disk.
**********************************************************************
Local llSuccess As Boolean

With This
   If Vartype(.AuditFileName) == TypeCharacter
      Try
         *** I'll use Try...Catch here because it may be possible to have no write righs to that folder
         StrToFile(EmptyString,.AuditFileName)
         Catch To oError
      EndTry
      If Vartype(oError) = TypeUndefined
         *** No errors occured
         llSuccess = True
      EndIf
   EndIf
EndWith
Return llSuccess
ENDPROC

PROCEDURE Init
**********************************************************************
* Program....: B-AuditMgr.Init
* Version....:
* Author.....: Grigore Dolghin :: mailto:gdolghin@yahoo.com
* Date.......: 04 November 2005, 03:09:22
* Notice.....: Copyright © 2005, Class Software.
* Compiler...: Visual FoxPro 09.00.0000.3307 for Windows
* Abstract...:
* Changes....: Administrator, Created 04 November 2005 / 03:09:22
* Parameters.:
* Called by..:
* Purpose....:
**********************************************************************
ENDPROC
ENDDEFINE
*
*-- EndDefine: b_auditmgr
**************************************************

Nota personala: constat cu supriza ca bucata de cod pe care am postat-o a facut destul de multe "valuri". Hm..... si daca ati sti cate chestii interesante mai am de aratat..... :)

Comentariul este gresit. Initial asa era, apoi am modificat codul, dar n-am mai modificat comentariul. Ideea e ca daca am setat clasa pe 2, se logheaza numai 0, 1 si 2. 3 sare din schema. Deci... If .VerboseLevel >= tnVerboseLevel. .VerboseLevel e setarea clasei, tnVerboseLevel vine din stringul care trebuie logat.