Nu pricep ceva, domnilor. Poate ma ajuta cineva.

Incerc sa-mi extind clasele din framework, adaugand la toate controalele care permit editarea textului un shortcut menu de genul Copy, Paste, Select All, etc. Executarea menului e simpla - in .RightClick am un DO EditShortcutMenu.mpr.

Am atasat meniul in acest mesaj. Merge bine, dar face ceva curios: Daca fac right click pe un textbox, desi clipboardul este gol (sunt sigur in privinta asta), optiunea Paste este activa. Daca o selectez, nu face nimic. In schimb, optiunea Paste din meniul Edit (ala din bara de meniuri) este inactiva.

Care-i diferenta? de ce una merge bine si cealalta nu? Stie cineva?

nu stiu daca va multumeste solutia gasita de mine, dar fac o incercare. precizez ca am schimbat fontul formularului (pentru ca numai cu Small Fonts merge figura), am facut edit1 un pic mai inalt, pentru a se vedea ca efectul este valabil ptr orice inaltime, si am pus un 1.5 in formula modificata, pe care sa nu ma intrebati de unde l-am luat.... un trial&error mic....

PUBLIC oform1
oform1=NEWOBJECT("form1")
oform1.Show
RETURN

DEFINE CLASS form1 AS form
   Top = 0
   Left = 0
   Height = 601
   Width = 312
   DoCreate = .T.
   Caption = "Form1"
   Themes = 0
   FontName = "Small Fonts"
   FontSize = 9

ADD OBJECT edit1 AS editbox WITH ;
   Height = 380, ;
   Left = 26, ;
   Top = 14, ;
   Width = 259, ;
   Value = 'Shortcut works properly here' + chr(13) + ;
   'But the shortcut is not display on cursor position'

ADD OBJECT edit2 AS editbox WITH ;
   Height = 80, ;
   Left = 26, ;
   Top = 406, ;
   Width = 259, ;
   Value = 'Shortcut does not work properly here' + chr(13) + ;
   'The shortcut is display on cursor position'

PROCEDURE DefinePopup
   DEFINE POPUP FoxShortcutMenu SHORTCUT RELATIVE FROM MROW(),MCOL()
   DEFINE BAR _med_undo OF foxshortcutmenu PROMPT "\<Undo" ;
      KEY CTRL+Z, "Ctrl+Z"
   DEFINE BAR _med_redo OF foxshortcutmenu PROMPT "Re\<do" ;
      KEY CTRL+R, "Ctrl+R"
   DEFINE BAR _med_sp100 OF foxshortcutmenu PROMPT "\-"
   DEFINE BAR _med_cut OF foxshortcutmenu PROMPT "Cu\<t" ;
      KEY CTRL+X, "Ctrl+X" PICTRES _med_cut
   DEFINE BAR _med_copy OF foxshortcutmenu PROMPT "\<Copy" ;
      KEY CTRL+C, "Ctrl+C" PICTRES _med_copy
   DEFINE BAR _med_paste OF foxshortcutmenu PROMPT "\<Paste" ;
      KEY CTRL+V, "Ctrl+V" PICTRES _med_paste
   DEFINE BAR _med_pstlk OF foxshortcutmenu PROMPT "Paste \<Special..."
   DEFINE BAR _med_clear OF foxshortcutmenu PROMPT "Cle\<ar"
   DEFINE BAR _med_sp200 OF foxshortcutmenu PROMPT "\-"
   DEFINE BAR _med_slcta OF foxshortcutmenu PROMPT "Se\<lect All" ;
      KEY CTRL+A, "Ctrl+A"
   DEFINE BAR _med_sp300 OF foxshortcutmenu PROMPT "\-"
   DEFINE BAR _med_find OF foxshortcutmenu PROMPT "\<Find..." ;
      KEY CTRL+F, "Ctrl+F"
   DEFINE BAR _med_repl OF foxshortcutmenu PROMPT "R\<eplace..." ;
      KEY CTRL+L, "Ctrl+L"
ENDPROC

PROCEDURE Unload
   Release popup FoxShortcutMenu
ENDPROC

Procedure Init
   ThisForm.DefinePopup()
EndProc

PROCEDURE edit1.RightClick
   Move Popup FoxShortcutMenu to (Mrow(ThisForm.Name, 0) - 1.5 * ;
     FONTMETRIC(4, ThisForm.FontName, ThisForm.FontSize) * ;
     (Mrow(ThisForm.Name, 0) / FONTMETRIC(1, ThisForm.FontName, ThisForm.FontSize))), ;
  Mcol(ThisForm.Name, 0) && <<---------<<
   ACTIVATE POPUP FoxShortcutMenu && at mrow(), mcol()
ENDPROC

PROCEDURE edit2.RightClick
   ThisForm.DefinePopup() && re-define the popup
   ACTIVATE POPUP FoxShortcutMenu
ENDPROC

ENDDEFINE